Wir reden ueber folgende Funktion

f[x_]=Sin[x]+Cos[2x]/2

1. Geometrische Veranschaulichung von Funktion (schwarz), erster Ableigung (rot) und zweiter Ableitung (blau):

Funktionswert an der Stelle x ~ Hoehe des Funktionsgraphen an dieser Stelle

erste Ableitung an der Stelle x ~ Steigung (= Steilheit, Aenderungsrate) des Funktionsgraphen an dieser Stelle

zweite Ableitung ~ Kruemmung des Funktionsgraphen ~ Steigung des Graphen der Ableitung

Bemerkenswert: Wo die Funktion extremal wird, hat sie keine Steigung (d.h. horizontale Tangente), d.h. die Ableitung ist null. Und wo die Ableitung extremal wird, d.h. wo die Steilheit der urspruenglichen Funktion extremal wird, da ist die zweite Ableitung null.

Manipulate[Plot[Evaluate[{f[x],If[first,f'[x], -10],If[second,f''[x], -10]}], {x,-5,5}, PlotRange -> 4,PlotStyle->{{Thick,Black},{Thick,Red},{Thick,Blue}},ImageSize->500,Epilog->{Black,Disk[{t,f[t]},.1],Red,If[first,Disk[{t,f'[t]},.1],{}],Blue,If[second,Disk[{t,f''[t]},.1],{}],If[first&&!second,{Black,Line[{{-5,f'[t]((-5)-t)+f[t]},{5,f'[t](5-t)+f[t]}}]},{}],If[first&&second,{Red,Line[{{-5,f''[t]((-5)-t)+f'[t]},{5,f''[t](5-t)+f'[t]}}]},{}],
If[second,{Black,Line[Table[{u,f[t]+f'[t](u-t)+1/2f''[t](u-t)^2},{u,-5,5,.1}]]},{}]}
],{first,{False,True}}, {second,{False,True}}, {t,-5,5}]

2. Satz von Taylor

Idee:  Ist eine Funktion f oft genug differenzierbar, z.B. n mal, dann kann man die Funktion (Subscript[T, n]) betrachten, die durch (Subscript[T, n])(x)=(∑_(k=0)^n)((Derivative[k][f](0) (x^k))/(k!)) definiert ist. Die ersten n Ableitungen dieser Funktion an der Stelle (Subscript[x, 0])=0 stimmen dann mit den ersten n Ableitungen der Funktion f an der Stelle (Subscript[x, 0])=0 ueberein. Man darf deshalb erwarten, dass der Graph von (Subscript[T, n]) in der Naehe von 0 eine gute Approximation den Graph von f darstellt.

Aber Achtung: Es ist nicht gesagt, dass groessere Werte von n zu guten Approximationen fuer einen groesseren Bereich fuehren. Das kann sein (im Beispiel f(x)=sin(x)+(1/2)cos(x) ist es so), muss aber nicht (zum Beispiel bei f(x)=1/(1+(x^2))wird die Approximation (Subscript[T, n]) fuer wachsende n nur im Intervall (-1,1) besser, ausserhalb dieses Bereichs ist sie unbrauchbar).

TaylorPolynom[f_,x_,n_]:=Sum[Derivative[k][f][0]/k!x^k,{k,0,n}]

TaylorPolynom[f,x,12]

Manipulate[Plot[Evaluate[{f[x],TaylorPolynom[f,x,n]}],{x,-5,5},PlotRange->{-2,2},PlotStyle->Thick,Epilog->Text[Style["n = "<>ToString[n],24],{-4.25,1.8}],ImageSize->500],{n,Range[0,20],ControlType->Slider}]